Für die Query ist in der GeoShop Datenbank eine Tabellen mit den notwendigen Attributen anzulegen.

Öffnen Sie die GeoShop Datenbank (defaultmässig eine ACCESS Datenbank).

Kreieren Sie darin eine neue Tabelle mit den notwendigen Attributen.

create table MYStrasse (
   FileID INTEGER,
   ObjID  INTEGER,
   Gemeinde CHAR(50),
   Strassenname CHAR(50),
   x DOUBLE,
   y DOUBLE
);

Die Tabelle muss folgende Felder beinhalten.

Die IL2GEO-Konfiguration für das INTERLIS Modell der Daten ist zu erweitern.

	Falls Sie eine bestehende Konfiguration aus dem System Verzeichnis erweitern wollen, so kopieren Sie diese und deren weitere Anteile zuerst aus dem System Verzeichnis in das User Verzeichnis.

Öffnen Sie die IL2GEO Konfiguration des INTERLIS Modelles mit einem Texteditor.

und erweitern Sie den Abschnitt der Includes am Ende des Files um folgende Eintrag.

:
|INCL \script\il2geo\il2geo.out
|INCL \script\il2geo\DM01AVCH24D.out
|INCL \script\il2geo\il2geo.prg

Sichern und schliessen Sie das File wieder.

Kreieren Sie das neue File, das Sie oben inkludiert haben, falls es nicht schon vorhanden ist (eventuell vom Kopieren aus dem System Verzeichnis).

In diesen File werden spezielle Output Prozeduren in iG/Script für die Integration der Daten in den GeoShop abgelegt. Dazu gehören Prozeduren die Datenbanktabellen mit den Daten füllen. Öffnen Sie das File in einem Texteditor und fügen Sie folgende Prozedur ein.

:
!----------------------------------------------------------------------------

PROCEDURE DB_MYSTRASSE_WRITE0

   ! Andwendbar auf Tabelle Gebaeudeadressen.LokalisationsNamePos

   ! Check Index
   !------------
   IF VAR.INDEX <> 1 THEN
      RETURN
   END_IF

   ! Test Object
   !------------
   IF 'IN.LokalisationsNamePos_von.Text' EXISTS NOT THEN
      RETURN
   END_IF
   IF IN.LokalisationsNamePos_von.Text IS_NULL THEN
      RETURN
   END_IF
   IF IN.Pos IS_NULL THEN
      RETURN
   END_IF

   ! build sql-insert-statement
   !---------------------------
   'insert into Mystrasse (FileID,ObjID,Gemeinde,Strassenname,x,y) values ('
      VAR.DB_FILE_ID APP ',' APP
      IN.GEOSHOP_ID APP ',' APP
      VAR.DB_GEMEINDE SQL_STRING APP ',' APP
      IN.LokalisationsNamePos_von.Text SQL_STRING APP ',' APP
      IN.Pos POINTX TO_STRING APP ',' APP
      IN.Pos POINTY TO_STRING APP
   ')' APP => VAR.DB_SQL

   ! execute sql-statement
   !----------------------
   IF VAR.DB_SQL DB.EXEC_SQL NOT THEN
      ERROR 'Can not insert MyStrasse (1): ',IN.LokalisationsNamePos_von.Text,' !'
      DISPLAY VAR.DB_SQL
      HALT
   END_IF

END_PROCEDURE

!----------------------------------------------------------------------------
:

Speichern und schliessen Sie das File.

Die Prozedur wird INTERLIS Objekte Gebaeudeadressen.LokalisationsNamePos in die Tabelle MyStrasse schreiben. Die Prozedur testet zuerst, ob alle notwendigen Bestandteile des Objektes vorhanden sind, bildet dann ein SQL Insert Statement und führt dieses aus.

Damit die Prozedur ausgeführt wird, muss diese in der Konfiguration eingetragen werden.

Öffnen Sie mit dem Konfigurationseditor IL2GEO die Konfiguration.

Abbildung 36. Konfigurationseditor GEOEDit Beispiel DB Procedure

Selektieren Sie unter INTERLIS Objects das Objekt Gebaeudeadressen.LokalisationsNamePos . Erzeugen Sie in GEO Objects mit GEO > New > Procedure einen neuen Procedure-Eintrag. Selektieren Sie unter Procedure Name die soeben erstellte Procedur DB_MYSTRASSE_WRITE0.

Speichern und schliessen Sie die Konfiguration.

Die Konfiguration wird beim Upload von INTERLIS Daten jeweils beim Objekt Gebaeudeadressen.LokalisationsNamePos die Procedure DB_MYSTRASSE_WRITE0 aufrufen, die das Objekt in die Tabelle MyStrasse schreibt.

Nun muss über eine Prozedur die Query definiert werden.

Öffnen Sie das File für die Prozeduren in einem Texteditor.

Fügen Sie folgende Procedur ein.

:
!----------------------------------------------------------------------------

PROCEDURE QUERY_UPDATE_MYSTRASSE

   ! Allgemeine Angaben zur Query
   !-----------------------------
   &QUERY_OBJECT MAPCLEAR
   'mystrasse' => QUERY_OBJECT.NAME
   'My Strasse' => QUERY_OBJECT.DISPLAY_NAME
   'mystrasse' => QUERY_OBJECT.TABLE
   '10000.0' => QUERY_OBJECT.ZOOMAREA
   '255,0,255,1.0' => QUERY_OBJECT.HIGHLIGHT_COLOR
   QUERY_CREATE_QUERY

   ! 1. Feld Gemeinde
   !-----------------
   &QUERY_FIELD MAPCLEAR
   'gemeinde' => QUERY_FIELD.NAME
   'Gemeinde' => QUERY_FIELD.DISPLAY_NAME
   'select distinct gemeinde from gs_strasse' => QUERY_FIELD.SQL
   5 => QUERY_FIELD.VISIBLE_VALUES
   QUERY_CREATE_FIELD

   ! 2. Feld Strasse
   !----------------
   &QUERY_FIELD MAPCLEAR
   'strassenname' => QUERY_FIELD.NAME
   'Strasse' => QUERY_FIELD.DISPLAY_NAME
   'select distinct gemeinde,strassenname from gs_strasse' => QUERY_FIELD.SQL
   'gemeinde' => QUERY_FIELD.DEPENDS_ON
   15 => QUERY_FIELD.VISIBLE_VALUES
   QUERY_CREATE_FIELD

   ! write Query
   !------------
   QUERY_WRITE_QUERY

END_PROCEDURE

!----------------------------------------------------------------------------
:

Speichern und schliessen Sie das File.

Die Prozedur definiert eine Query mit dem Namen mystrasse. Der Namen der Prozedur muss zwingend den Prefix QUERY_UPDATE_ aufweisen. Die Prozedur definiert die Query und die Felder der Query. Die Prozedur wird automatisch am Ende eines Uploads der INTERLIS Daten ausgeführt.

Bisher wurden nur Definitionen für die Query konfiguriert. Damit die Query erstellt wird, müssen Daten des INTERLIS Modelles in den GeoShop geladen werden.

Uploaden Sie deshalb ein File des INTERLIS Modelles in den GeoShop

Beim Upload Prozess wird nun Datenbanktabelle mit Objekten des Files gefüllt. Am Schluss wird die Query erstellt und unter dem Namen wie folgt abgelegt.

Die Query beinhaltet folgende Definitionen.

MAP
   name STRING mystrasse
   display_name STRING 'My Strasse'
   table STRING mystrasse
   zoomarea REAL 10000.0
   highlight_color STRING 255,0,255,1.0
   fields LIST
      MAP
         name STRING gemeinde
         display_name STRING 'Gemeinde'
         visible_values INT 5
         values LIST
            STRING 'Demogemeinde'
         }
      }
      MAP
         name STRING strassenname
         display_name STRING 'Strasse'
         depends_on STRING gemeinde
         visible_values INT 15
         values LIST
            STRING 'Demogemeinde,Aescherstrasse'
            STRING 'Demogemeinde,Aettenbergstrasse'
            STRING 'Demogemeinde,Aettenbergweg'
            :
            STRING 'Demogemeinde,Zürcherstrasse'
         }
      }
   }
}

Die Datenbanktabelle und die Query wird bei jedem Upload von Daten nachgeführt und aktualisiert.